AddSysTrayIcon()

Syntax

Ergebnis = AddSysTrayIcon(#SysTrayIcon, WindowID, ImageID)

Fügt ein Icon in den "SysTray" Bereich hinzu.

Wenn ein Ereignis auf irgendeinem der SysTray Icons auftritt, wird ein #PB_Event_SysTray Ereignis zurückgegeben. EventGadget() kann benutzt werden, um das benutzte SysTrayIcon zu ermitteln. Der EventType() Befehl wird ebenfalls durch diesen Befehl aktualisiert.

Parameter

#SysTrayIcon	Eine Nummer zum Identifizieren des neuen SysTray-Icons. #PB_Any kann verwendet werden, um diese Zahl automatisch zu generieren.
WindowID	Das Fenster, auf dem die SysTray-Ereignisse verwaltet werden. WindowID() kann verwendet werden, um diesen Wert zu erhalten.
ImageID	Das für das SysTray-Icon zu verwendende Bild. Es ist ratsam, ein PNG-Bild zu verwenden, um einen Transparenz-Layer zu haben. ImageID() kann benutzt werden, um einfach diese ID zu ermitteln.

Rückgabewert

Ein Wert ungleich Null, wenn das SysTray-Icon erfolgreich hinzugefügt wurde, andernfalls Null.

Anmerkungen

Alle SysTray-Icons werden automatisch entfernt, wenn das Programm endet.
Beim QT-Subsystem gibt der Linksklick ein Doppelklick-Linksklick-Ereignis zurück und der Mittelklick ein Linksklick-Ereignis.
Für den normalen Betrieb muss ein Systray-Ereignis immer mit einem Menü verknüpft sein.

Beispiel

  ; Unsichtbares Fenster, um nur den SysTray anzuzeigen
  OpenWindow(0, 0, 0, 10, 10, "", #PB_Window_Invisible)

  UsePNGImageDecoder()
  AddSysTrayIcon(0, WindowID(0), LoadImage(0, #PB_Compiler_Home + "examples/sources/Data/world.png"))

  ; Erstellt ein Popup-Menü, das im SysTray im SysTray-Look angezeigt wird
  CreatePopupImageMenu(0, #PB_Menu_SysTrayLook)
    MenuItem(0, "About PureBasic...")
    MenuBar()
    MenuItem(1, "Exit")

  ; Verknüpft das Menü mit dem SysTray
  SysTrayIconMenu(0, MenuID(0))

  Repeat
    Select WaitWindowEvent()
      Case #PB_Event_Menu
        Select EventMenu()
          Case 1 ; Exit 
            RemoveSysTrayIcon(0)
            End
        EndSelect
    EndSelect
  ForEver

Siehe auch

RemoveSysTrayIcon(), ChangeSysTrayIcon()

Unterstützte OS

Alle