FontRequester()

Syntax

Ergebnis = FontRequester(FontName$, FontGröße, Flags [, Farbe [, Stil]])
Beschreibung
Öffnet den Standard-Requester zum Auswählen eines Zeichensatzes.

Die Befehle SelectedFontColor(), SelectedFontName(), SelectedFontSize() und SelectedFontStyle() können nach einem erfolgreichen Aufruf benutzt werden, um die benötigten Informationen über den ausgewählten Zeichensatz zu erhalten.

Parameter

FontName$ Der zu verwendende Standard-Fontname, wenn der Requester geöffnet wird.
FontGröße Die zu verwendend Standard-Fontgröße, wenn der Requester geöffnet wird.
Flags Dies kann kann einer der folgenden Werte sein:
  #PB_FontRequester_Effects : Aktiviert die "Effekte" des Requesters, einschließlich Farbauswahl (nur auf Windows).
Farbe (optional) Legt die Standardfarbe fest, wenn der Requester geöffnet wird. Einen gültigen Farbwert erhalten Sie mit dem Befehl RGB().
Stil (optional) Legt den Standardstil fest, wenn der Requester geöffnet wird. Siehe SelectedFontStyle() für die verfügbaren Stile.

Rückgabewert

Ein Wert ungleich Null, wenn ein Zeichensatz ausgewählt wurde, und Null wenn der Nutzer den Requester abgebrochen hat.

Beispiel

  FontName$ = "Arial"   ; Anfangs-Zeichensatz festlegen  (Kann auch ein leer sein)
  FontSize  = 14        ; Anfangs-Größe festlegen  (kann auch Null sein)
  Result = FontRequester(FontName$, FontSize, #PB_FontRequester_Effects)
  If Result
    Message$ = "Sie haben folgenden Zeichensatz ausgewählt:"  + #LF$ 
    Message$ + "Name:  " + SelectedFontName()       + #LF$
    Message$ + "Größe: " + Str(SelectedFontSize())  + #LF$
    Message$ + "Farbe: " + Str(SelectedFontColor()) + #LF$
    If SelectedFontStyle() & #PB_Font_Bold
      Message$ + "Fett" + #LF$
    EndIf
    If SelectedFontStyle() & #PB_Font_StrikeOut
      Message$ + "Durchgestrichen" + #LF$
    EndIf
    If SelectedFontStyle() & #PB_Font_Underline
      Message$ + "Unterstrichen" + #LF$
    EndIf
  Else 
    Message$ = "Der Requester wurde abgebrochen."
  EndIf
  
  MessageRequester("FontRequester", Message$, #PB_MessageRequester_Ok) 

Siehe auch

SelectedFontColor(), SelectedFontName(), SelectedFontSize(), SelectedFontStyle()

Unterstützte OS

Alle

<- ColorRequester() - Requester Inhaltsverzeichnis - InputRequester() ->