SendMail()

Syntaxe

Resultat = SendMail(#Courrier, Smtp$ [, Port [, Options [, Identifiant$, MotdePasse$]]])

Envoie un courrier.

Arguments

#Courrier	Le courrier à envoyer.
Smtp$	L'adresse du serveur d'envoi de courrier.
Port (optionnel)	Le port du serveur mail (par défaut 25).
Options (optionnel)	Peut être une combinaison des valeurs suivantes: #PB_Mail_Asynchronous: Envoie le courrier en arrière-plan. Utiliser MailProgress() pour suivre la progression. #PB_Mail_UseSSL : Envoie le courrier avec TLS/SSL (le serveur doit supporter ce protocole). #PB_Mail_UseSMTPS : Envoie le courrier avec SMTPS (le serveur doit supporter ce protocole). #PB_Mail_Debug : Imprimer les informations de débogage dans la console.
Identifiant$, MotdePasse$ (optionnel)	L'utilisateur et le mot de passe utilisé pour l'authentification SMTP, si le serveur les requiert.

Valeur de retour

Renvoie une valeur non nulle si le courrier a été envoyé avec succès, zéro sinon.

Exemple: Simple SMTP

  ; Note: changez l'adresse de destination et le smtp pour avoir un exemple fonctionnel.
  ;
  If CreateMail(0, "test@votreadresse.com", "Salut")
    AddMailRecipient(0, "votreadresse@domaine.com", #PB_Mail_To)
    
    Debug SendMail(0, "smtp.votresmtpici.com") 
  EndIf

Exemple: Utiliser Hotmail (TLS)

  Identifiant$ = "moi@hotmail.com"
  MotdePasse$ = "MotdePasse"
  Destinataire$ = "test@gmail.com"

  If CreateMail(0, Identifiant$, "Hello")
    AddMailRecipient(0, Destinataire$, #PB_Mail_To)
    Debug SendMail(0, "smtp-mail.outlook.com", 587, #PB_Mail_UseSSL, Identifiant$, MotdePasse$)
  EndIf

Exemple: Utiliser GMail (TLS+SMTPS)

  ; Assurez-vous d'utiliser le bon login et le bon mot de passe
  ;
  Identifiant$ = "votrelogin"
  MotdePasse$ = "MotdePasse"
  Destinataire$ = "test@gmail.com"
  
  If CreateMail(0, Identifiant$ + "@gmail.com", "Hello")
    AddMailRecipient(0, Destinataire$, #PB_Mail_To)
    Debug SendMail(0, "smtp.gmail.com", 465, #PB_Mail_UseSSL | #PB_Mail_UseSMTPS, Identifiant$, MotdePasse$)
  EndIf

Voir aussi

CreateMail(), MailProgress()

OS Supportés

Tous