RemoveGadgetItem()

Syntax

RemoveGadgetItem(#Gadget, Position)

Removes an item of the specified gadget.

Parameters

#Gadget	The gadget to use.
Position	The item to remove. The first item has the index 0.

Return value

None.

Remarks

The gadget type can be one of the following:

- ComboBoxGadget()
- EditorGadget()
- PanelGadget()
- ListViewGadget()
- ListIconGadget()
- MDIGadget()
- TreeGadget() - If the removed item is a node, all child-items will be removed too.

Example: Remove selected item in a ListIconGadget by pressing 'Delete'

  Enumeration 
    #KeyDelete
  EndEnumeration
  
  If OpenWindow(0, 100, 100, 300, 500, "ListIcon Example", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    ListIconGadget(0, 5, 5, 290, 290, "Number", 100, #PB_ListIcon_FullRowSelect | #PB_ListIcon_AlwaysShowSelection)
    For i=1 To 100
      AddGadgetItem(0, -1, Str(i))
    Next
    StringGadget(1, 5, 305, 290, 25, "Edit me!")
    EditorGadget(2, 5, 335, 290, 100)
    SetGadgetText(2, "And me too!")
    
    Repeat
      Event = WaitWindowEvent()
      If GetActiveGadget() = 0
        AddKeyboardShortcut(0, #PB_Shortcut_Delete, #KeyDelete)
      Else
        RemoveKeyboardShortcut(0, #PB_Shortcut_Delete)
      EndIf
      If Event = #PB_Event_Menu And EventMenu() = #KeyDelete
        i = GetGadgetState(0)
        If i > -1
          RemoveGadgetItem(0, i)
          SetGadgetState(0, i)
        EndIf
      EndIf
    Until Event = #PB_Event_CloseWindow
  EndIf

See Also

AddGadgetItem(), ClearGadgetItems(), CountGadgetItems()

Supported OS

All