PathPointX()

Syntax

Ergebnis.d = PathPointX(Distanz.d)

Gibt die X-Koordinate des Punktes an der angegebenen Distanz vom Beginn des aktuellen Vektorzeichnen-Pfades zurück.

Parameter

Distanz.d

Gibt die Distanz vom Beginn des Pfades an. Wenn dieser Parameter negativ oder größer als die Gesamtpfadlänge ist, dann wird der Start/Endpunkt des Pfades zurückgegeben. Die vollständige Länge des Pfades kann mit PathLength() ermittelt werden.

Rückgabewert

Die X-Koordinate des Punktes im Pfad.

Beispiel

  If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)

    If StartVectorDrawing(CanvasVectorOutput(0))
    
      ; Pfad konstruieren
      MovePathCursor(150, 125)
      AddPathCurve(0, 270, 0, -150, 350, 180)
      
      ; Position & Winkel des Punktes im Pfad ermitteln
      x = PathPointX(200)
      y = PathPointY(200)
      a = PathPointAngle(200)
      
      ; Zeichnet den Pfad
      VectorSourceColor($FF0000FF)
      StrokePath(5)
      
      ; Zeichnet eine Markierung am Pfad-Punkt
      AddPathCircle(x, y, 10)
      VectorSourceColor($FFFF0000)
      FillPath()
      
      MovePathCursor(x, y)
      AddPathLine(30*Cos(Radian(a)), 30*Sin(Radian(a)), #PB_Path_Relative)
      StrokePath(5)

      StopVectorDrawing()
    EndIf
    
    Repeat
      Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
  EndIf

Siehe auch

PathPointY(), PathPointAngle(), PathLength()

Unterstützte OS

Alle