AddPathCircle()

Syntax

AddPathCircle(x.d, y.d, Radius.d [, StartWinkel.d, EndWinkel.d [, Flags]])
Beschreibung
Fügt einen Kreis (oder einen Teilkreis) zum Vektorzeichnen-Pfad hinzu.

Standardmäßig beendet diese Funktion die aktuelle Figur im Pfad und fügt den Kreis als eine unverbundene Figur zum Pfad hinzu (volle Kreise werden als geschlossen markiert). Dieses Verhalten kann mit den entsprechenden Flags geändert werden.

Parameter

x.d, y.d Geben den Mittelpunkt des Kreises an.
Radius.d Gibt den Radius des Kreises an.
StartWinkel.d, EndWinkel.d (optional) Geben den Winkel (in Grad) für Beginn und Ende des Kreise an. Der Winkel 0 befindet sich an der positiven X-Achse. Die Standardwerte lauten 0 bzw. 360 Grad.
Flags (optional) Dies kann eine Kombination der folgenden Werte sein:
  #PB_Path_Default         : Kein spezielles Verhalten (Standardwert)
  #PB_Path_Relative        : Die Positionen sind relativ zur letzten Cursor-Position.
  #PB_Path_Connected       : Der Kreis ist mit dem existierenden Pfad durch eine Linie
                             verbunden und nicht automatisch eine geschlossene Figur.
  #PB_Path_CounterClockwise: Die Zeichenrichtung zwischen den Start-/End-Winkeln
                             verläuft gegen den Uhrzeigersinn.

Rückgabewert

Diese Funktion gibt keinen Wert zurück.

Anmerkungen

Diese Funktion ist gedacht für die Erstellung eigenständiger Kreise oder Kreisbögen. Um Figuren mit abgerundeten Ecken zu zeichnen, kann die AddPathArc() Funktion verwendet werden, welche automatisch die richtigen Winkel und den Mittelpunkt berechnet, um abgerundete Ecken zu zeichnen.

Beispiel

  If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)

    If StartVectorDrawing(CanvasVectorOutput(0))

      ; Teilkreis
      AddPathCircle(100, 100, 75, 0, 235)
      
      ; Teilkreis mit Linien zum Mittelpunkt
      MovePathCursor(300, 100)
      AddPathCircle(300, 100, 75, 0, 235, #PB_Path_Connected)
      ClosePath()
      
      VectorSourceColor(RGBA(255, 0, 0, 255))
      StrokePath(10)
    
      StopVectorDrawing()
    EndIf
    
    Repeat
      Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
  EndIf

Siehe auch

MovePathCursor(), AddPathLine(), AddPathArc(), AddPathBox(), AddPathEllipse(), AddPathCurve()

Unterstützte OS

Alle

<- AddPathBox() - VectorDrawing Inhaltsverzeichnis - AddPathCurve() ->