DisableToolBarButton()

Syntax

DisableToolBarButton(#ToolBar, Schalter, Status)

Deaktiviert (oder aktiviert) einen Werkzeugleisten-Schalter auf der angegebenen Werkzeugleiste.

Parameter

#ToolBar	Die zu verwendende Werkzeugleiste.
Schalter	Der zu deaktivierende bzw. zu aktivierende Werkzeugleisten-Schalter.
Status	Der neue Status des Werkzeugleisten-Schalters. Ein Wert von 1 deaktiviert den Werkzeugleisten-Schalter, und ein Wert von 0 aktiviert ihn.

Rückgabewert

Diese Funktion gibt keinen Wert zurück.

Beispiel

If OpenWindow(0, 0, 0, 180, 60, "ToolBar", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    If CreateToolBar(0, WindowID(0))
      UsePNGImageDecoder()
      Path$ = #PB_Compiler_Home  + "Examples" + #PS$ + "Sources" + #PS$ + "Data" + #PS$ + "ToolBar" + #PS$ + ""
      ToolBarImageButton(0, LoadImage(0, Path$ + "New.png"))
      ToolBarImageButton(1, LoadImage(1, Path$ + "Open.png"))
      ToolBarImageButton(2, LoadImage(2, Path$ + "Save.png"))
      DisableToolBarButton(0, 1, 1) : Disabled = #True
    EndIf

    ButtonGadget(0, 10, 30, 130, 20, "Enable OpenFile")
    ResizeGadget(0, #PB_Ignore, #PB_Ignore, GadgetWidth(0, #PB_Gadget_RequiredSize), #PB_Ignore)
    
    Repeat
      Event = WaitWindowEvent()
      If Event = #PB_Event_Gadget
        If EventGadget() = 0
          If Disabled = #True
            DisableToolBarButton(0, 1, 0)
            SetGadgetText(0,"Disable OpenFile")
            ResizeGadget(0, #PB_Ignore, #PB_Ignore, GadgetWidth(0, #PB_Gadget_RequiredSize), #PB_Ignore)
            Disabled = #False
          Else
            DisableToolBarButton(0, 1, 1)
            SetGadgetText(0,"Enable OpenFile")
            ResizeGadget(0, #PB_Ignore, #PB_Ignore, GadgetWidth(0, #PB_Gadget_RequiredSize), #PB_Ignore)
            Disabled = #True
          EndIf
        EndIf
      EndIf
    Until Event = #PB_Event_CloseWindow 
  EndIf

Siehe auch

ToolBarImageButton()

Unterstützte OS

Alle