ConvertCoordinateX()

Syntaxe

Resultat.d = ConvertCoordinateX(X.d, Y.d [, Source, Cible])

Convertit un point d'un système de coordonnées dans un autre.

Arguments

X.d, Y.d

Les coordonnées du point à convertir.

Source, Cible (optionnel)

Indique les systèmes de coordonnées source et cible à utiliser. Chacun d'eux peut être l'une des valeurs suivantes: #PB_Coordinate_Device: Le système de coordonnées du dispositif de sortie #PB_Coordinate_Output: Le système de coordonnées comme il a été créé avec la fonction de sortie de dessin #PB_Coordinate_User : Change le système de coordonnées des points du chemin de dessin #PB_Coordinate_Source: Change le système de coordonnées de la source du dessin vectoriel La conversion par défaut va de #PB_Coordinate_User vers #PB_Coordinate_Output.

Valeur de retour

Renvoie la coordonnée X du point dans le système de coordonnées cible.

Remarques

La coordonnée Y peut être récupérée avec la fonction ConvertCoordinateY().

Voir l'aperçu de VectorDrawing pour une introduction aux différents systèmes de coordonnées.

Exemple

  ; Cet exemple dessine un point à l'emplacement de la souris, même dans un système de coordonnées modifiées
  ; en utilisant les coordonnées du dispositif (pixels) en coordonnées de l'utilisateur (point)
  ;
  If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)   
    
    Repeat
      Event = WaitWindowEvent()
      
      If Event = #PB_Event_Gadget And EventGadget() = 0 And EventType() = #PB_EventType_LeftButtonDown
        
        If StartVectorDrawing(CanvasVectorOutput(0, #PB_Unit_Point))
          RotateCoordinates(0, 0, 30)
          
          CanvasX = GetGadgetAttribute(0, #PB_Canvas_MouseX)
          CanvasY = GetGadgetAttribute(0, #PB_Canvas_MouseY)
          
          DrawingX = ConvertCoordinateX(CanvasX, CanvasY, #PB_Coordinate_Device, #PB_Coordinate_User)
          DrawingY = ConvertCoordinateY(CanvasX, CanvasY, #PB_Coordinate_Device, #PB_Coordinate_User)
          
          AddPathCircle(DrawingX, DrawingY, 10)
          VectorSourceColor(RGBA(Random(255), Random(255), Random(255), 255))
          FillPath()
        
          StopVectorDrawing()
        EndIf
        
      EndIf
      
    Until Event = #PB_Event_CloseWindow
  EndIf

Voir aussi

ResetCoordinates(), TranslateCoordinates(), ScaleCoordinates(), RotateCoordinates(), SkewCoordinates(), FlipCoordinatesX(), FlipCoordinatesY(), ConvertCoordinateY()

OS Supportés

Tous