BeginVectorLayer()

Syntaxe

BeginVectorLayer([Transparence])

Commence une nouvelle couche vide au-dessus du dessin vectoriel en cours.

Désormais, toutes les opérations de dessin seront effectuées sur cette couche jusqu'à ce que EndVectorLayer() soit appelée.

Arguments

Transparence (optionnel)

Le niveau de transparence (alpha) de la nouvelle couche. Entre 0 (transparent) et 255 (opaque par défaut).

Valeur de retour

Aucune.

Remarques

Cette commande enregistre également l'état de dessin courant de la même manière que SaveVectorState().

Plusieurs couches peuvent être créées.

Les ressources nécessaires pour créer la couche temporaire dépendent de la taille du chemin clippé. Il est donc recommandé de définir un chemin de détourage qui ne couvre que la zone nécessaire afin d'économiser les ressources et d'améliorer les performances de dessin.

Exemple

  If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)

    If StartVectorDrawing(CanvasVectorOutput(0))

      ; Dessin semi-transparent sur la couche de base
      AddPathCircle(75, 100, 60)      
      VectorSourceColor(RGBA(255, 0, 0, 127))
      FillPath()      
      AddPathCircle(125, 100, 60)
      VectorSourceColor(RGBA(0, 0, 255, 127))
      FillPath()    
      
      ; Dessin opaque sur une couche semi-transparente
      BeginVectorLayer(127)
        AddPathCircle(275, 100, 60)    
        VectorSourceColor(RGBA(255, 0, 0, 255))
        FillPath()        
        AddPathCircle(325, 100, 60)
        VectorSourceColor(RGBA(0, 0, 255, 255))
        FillPath()    
      EndVectorLayer()
    
      StopVectorDrawing()
    EndIf
    
    Repeat
      Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
  EndIf

Voir aussi

EndVectorLayer(), SaveVectorState()

OS Supportés

Tous