MouseButton()

Syntaxe

Resultat = MouseButton(Bouton)
Description
Teste si un bouton est enfoncé.

Arguments

Bouton
  #PB_MouseButton_Left  : Teste si le bouton gauche de la souris est enfoncé
  #PB_MouseButton_Right : Teste si le bouton droit de la souris est enfoncé
  #PB_MouseButton_Middle: Teste si le bouton du milieu de la souris est enfoncé

Valeur de retour

Renvoie une valeur non nulle si le bouton spécifié est appuyé, zéro sinon.

Remarques

On peut appuyer sur plusieurs boutons simultanément.

ExamineMouse() doit être appelé avant cette fonction pour mettre l'état des boutons à jour.

Exemple

 ; Initialisation du monde 2D
 InitSprite()
 InitKeyboard()
 InitMouse()

  ; Ouverture de la fenêtre
  OpenWindow(0,0,0,800,600,"Souris - MouseButton",#PB_Window_ScreenCentered|#PB_Window_SystemMenu)
  OpenWindowedScreen(WindowID(0),0,0,800,600,1,0,0)

  ; Gestion de la fenêtre et de l'écran
  Repeat
   Repeat         ; Gestion de la fenêtre
     Event  = WindowEvent() 
   Until Event = 0
  
   ExamineMouse() ; Etat de la souris
  
   ; Affichage de l'état des boutons de la souris
   StartDrawing(ScreenOutput())
   DrawText(10,10, "Appuyer sur une touche du clavier pour quitter.", RGB(255,255,0))
   DrawText(200,180, "Cliquez sur le bouton gauche, milieu ou droit de la souris.", RGB(255,0,0),RGB(255,255,0))
    If MouseButton(#PB_MouseButton_Left) <> 0
     DrawText(200,230, "Bouton Gauche", RGB(255,0,0),RGB(255,255,0))
   Else
     DrawText(200,230, "Bouton Gauche", RGB(255,255,255))
   EndIf
   If MouseButton(#PB_MouseButton_Middle) <> 0
     DrawText(350,230, "Bouton Central", RGB(255,0,0),RGB(255,255,0))
   Else
     DrawText(350,230, "Bouton Central", RGB(255,255,255))
   EndIf
   If MouseButton(#PB_MouseButton_Right) <> 0  
     DrawText(500,230, "Bouton Droit", RGB(255,0,0),RGB(255,255,0))
   Else
     DrawText(500,230, "Bouton Droit", RGB(255,255,255))
   EndIf  
   StopDrawing()
   
   FlipBuffers()
   ClearScreen(RGB(0,0,0)) 
  
   ExamineKeyboard()
  Until KeyboardPushed(#PB_Key_All)
  End

Voir aussi

ExamineMouse()

OS Supportés

Tous

<- InitMouse() - Mouse Index - MouseDeltaX() ->