HideMenu()

Syntaxe

HideMenu(#Menu, Etat)

Cache ou affiche un menu.

Arguments

#Menu	Le menu à utiliser.
Etat	#True : Le menu est caché #False : Le menu est affiché

Valeur de retour

Aucune.

Exemple: Cache/Affiche un Menu

  If OpenWindow(0, 200, 200, 300, 100, "Exemple HideMenu")
    ButtonGadget(0, 70, 10, 150, 30, "Cache/Affiche menu")
    If CreateMenu(0, WindowID(0))
      MenuTitle("Projet")
      MenuItem(1, "Nouveau")
      MenuItem(2, "Ouvrir")
    EndIf
    
    Repeat
      Select WaitWindowEvent()
        Case #PB_Event_Gadget
          Select EventGadget()
            Case 0
              ;Définir l'état du bouton bascule (activé/désactivé) du menu :
              Toggle = Bool(Not Toggle)
              HideMenu(0, Toggle)
              ; Ajuste la position verticale du bouton en fonction de la présence du menu :
              If Toggle
                ResizeGadget(0, #PB_Ignore, 10 + MenuHeight(), #PB_Ignore, #PB_Ignore)
              Else
                ResizeGadget(0, #PB_Ignore, 10, #PB_Ignore, #PB_Ignore)
              EndIf
          EndSelect
        Case #PB_Event_CloseWindow
          Break
      EndSelect
    ForEver
  EndIf

Exemple: Change de Menu

  If OpenWindow(0, 200, 200, 300, 100, "Exemple HideMenu")
  ButtonGadget(0,70,10,150,30,"Change de menu")
  If CreateMenu(0, WindowID(0))
    MenuTitle("Projet")
    MenuItem(1, "Nouveau")
    MenuItem(2, "Ouvrir") 
  EndIf
  If CreateMenu(1, WindowID(0))
    MenuTitle("Menu")
    MenuItem(1, "Enregistrer")
    MenuItem(2, "Quitter") 
  EndIf
  
  HideMenu(0,#False) ; Affiche le menu "Projet" 
  Repeat
    Event = WaitWindowEvent()          
    If Event = #PB_Event_Gadget  
      Select EventGadget()
        Case 0 
          HideMenu(1,#False) ; Affiche le menu "Menu" 
      EndSelect
      
    EndIf
  Until Event = #PB_Event_CloseWindow
  EndIf

Voir aussi

CreateMenu(), CreateImageMenu()

OS Supportés

Windows, Linux