DisplayPopupMenu()

Syntaxe

DisplayPopupMenu(#Menu, FenetreID, [X, Y])
Description
Affiche un Menu contextuel (pop-up).

Arguments

#Menu Le menu contextuel, avec ou sans images, à afficher.
FenetreID La fenêtre qui accueille le nouveau menu contextuel.

Ce numéro peut être obtenu avec la fonction WindowID().
X, Y (optionnel) Les coordonnées écran où apparaîtra le menu contextuel, en pixel depuis le coin en haut et à gauche de l'écran primaire.

Si ce paramètre n'est pas spécifié, le menu est affiché à la position de la souris.

Valeur de retour

Aucune.

Remarques

Le menu contextuel se ferme automatiquement quand on clique sur un menu ou quand on clique en dehors du menu.

Exemple

  If OpenWindow(0, 200, 200, 220, 120, "Exemple de menu contextuel")
    If CreatePopupMenu(0)        ; La création du menu contextuel commence...
      MenuTitle("Projet")        ; Vous pouvez utiliser toutes les commandes relatives au menu,
        MenuItem(1, "Ouvrir")    ; comme si c'était un menu normal...
        MenuItem(2, "Enregistrer")
        MenuItem(3, "Enregistrer sous")
        MenuItem(4, "Quitter")
        MenuBar()
        OpenSubMenu("Fic&hiers récents")
          MenuItem(5, "PureBasic.exe")
          MenuItem(6, "Test.txt")
        CloseSubMenu()

    EndIf
    Repeat
      Event = WaitWindowEvent()
      Select Event                        ; Examine quel type d'évènement est survenu sur la fenêtre
        Case #PB_Event_RightClick         ; Le bouton droit de la souris a été clické =>
          DisplayPopupMenu(0,WindowID(0)) ; On affiche le menu contextuel
        
        Case #PB_Event_Menu      ; Un élément du menu a été sélectionné
          Select EventMenu()     ; On recupère le numéro de cet élement...
            Case 1 : Debug "Menu : Ouvrir"
            Case 2 : Debug "Menu : Enregistrer"
            Case 3 : Debug "Menu : Enregistrer sous"
            Case 4 : End
            Case 5 : Debug "Menu : PureBasic.exe"
            Case 6 : Debug "Menu : Text.txt"
          EndSelect

      EndSelect
    Until Event = #PB_Event_CloseWindow
  EndIf

Voir aussi

CreatePopupMenu(), CreatePopupImageMenu()

OS Supportés

Tous

<- DisableMenuItem() - Menu Index - FreeMenu() ->