SetGadgetItemData()

Syntaxe

SetGadgetItemData(#Gadget, Element, Valeur)

Associe une valeur à un élément d'un gadget.

Arguments

#Gadget	Le gadget à utiliser.
Element	L'élément à utiliser. Le premier élément commence à 0.
Valeur	La valeur à définir.

Valeur de retour

Aucune.

Remarques

Cette valeur peut être récupérée avec la commande GetGadgetItemData().

Si l'index de l'élément change (par exemple d'autres éléments sont effacés), la valeur restera toujours associée à son élément.

Cette commande est supportée par les gadgets suivants:

- ComboBoxGadget()
- ListIconGadget()
- ListViewGadget()
- PanelGadget()
- TreeGadget()

Exemple

  ; Ce programme utilise SetGadgetItemData pour stocker la position d'origine
  ; de chaque élément pour la connaitre plus tard, même si l'index des éléments a changé.
  ;
  If OpenWindow(0, 0, 0, 290, 250, "SetGadgetItemData", #PB_Window_SystemMenu | #PB_Window_ScreenCentered) 
    ButtonGadget(0,  10, 10, 80, 20, "Ajouter")
    ButtonGadget(1, 100, 10, 80, 20, "Supprimer") 
    ButtonGadget(2, 190, 10, 80, 20, "Test")
    ListViewGadget(3, 10, 40, 260, 200)
    For i = 0 To 10
      AddGadgetItem(3, i, "Ancien élément "+Str(i))
      SetGadgetItemData(3, i, i)
    Next i
   
    Repeat
      Evenement = WaitWindowEvent()
      If Evenement = #PB_Event_Gadget
        element = GetGadgetState(3)
       
        Select EventGadget()       
          Case 0 ; Ajouter         
            AddGadgetItem(3, element, "Nouvel élément")
            If element <> -1
              SetGadgetItemData(3, element, -1)
            Else
              SetGadgetItemData(3, CountGadgetItems(3)-1, -1)
            EndIf
           
          Case 1 ; Supprimer
            If element <> -1
              RemoveGadgetItem(3, element)
            EndIf
           
          Case 2 ; Test
            If element <> -1
              valeur = GetGadgetItemData(3, element)
              If valeur = -1
                MessageRequester("", "C'est un nouvel élément")
              Else
                MessageRequester("", "C'était l'élément numéro "+Str(valeur))
              EndIf
            EndIf
                     
        EndSelect
      EndIf
    Until Evenement = #PB_Event_CloseWindow
  EndIf

Voir aussi

GetGadgetItemData(), GetGadgetData(), SetGadgetData()

OS Supportés

Tous