VectorSourceImage()

Syntax

VectorSourceImage(ImageID [, Alpha [, Breite.d, Höhe.d [, Flags]]])

Wählt ein Bild als Quelle für Vektorzeichnen-Operationen wie FillPath() oder StrokePath() aus. Diese Funktionen werden Pixel vom angegebenen Bild auf die Zeichenausgabe anwenden, wo immer sie etwas zeichnen.

Parameter

ImageID	Gibt das als Quelle zu verwendende Bild an. Verwende die ImageID() Funktion, um diesen Wert von einem Bild zu erhalten.
Alpha (optional)	Gibt eine optionale Alpha-Transparenz an, die auf das Quellbild angewendet werden soll. Diese Transparenz wird zusätzlich zu allen im Quellbild bereits vorhandenen transparenten Pixeln angewandt. Der Standardwert ist 255 (keine zusätzliche Transparenz).
Breite.d, Höhe.d (optional)	Geben eine optionale Breite und Höhe für das Bild an. Die Werte werden in Bezug auf das #PB_Coordinate_Source Koordinatensystem interpretiert. Wenn keine Breite und Höhe angegeben werden, dann werden die Abmessungen des Quellbildes (in Pixel) in die Einheit der Vektorzeichnen-Ausgabe konvertiert und so verwendet (d.h. das Bild hat seine originale Größe).
Flags (optional)	Dies kann einer der folgenden Werte sein: #PB_VectorImage_Default: Bereiche außerhalb des Quellbildes sind transparent (Standard) #PB_VectorImage_Repeat : Das Quellbild wird wiederholt, um den gesamten Zeichenbereich abzudecken

Rückgabewert

Diese Funktion gibt keinen Wert zurück.

Anmerkungen

Siehe den Vektorzeichnen Überblick für eine Einführung in die verschiedenen Koordinatensysteme.

Durch Umwandlung des #PB_Coordinate_Source Koordinatensystems kann das verwendete Quellbild umgewandelt (verschoben, gedreht, gestreckt, verzerrt) werden. Siehe das zweite Beispiel unten für eine Demonstration.

Beispiel: Wiederholtes Quellbild

  If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)
    
    LoadImage(0, #PB_Compiler_Home + "examples/Sources/Data/PureBasicLogo.bmp")

    If StartVectorDrawing(CanvasVectorOutput(0))

      AddPathBox(50, 50, 200, 50)
      AddPathBox(150, 75, 200, 50)
      
      VectorSourceImage(ImageID(0), 255, ImageWidth(0), ImageHeight(0), #PB_VectorImage_Repeat)
      StrokePath(20)
    
      StopVectorDrawing()
    EndIf
    
    Repeat
      Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
  EndIf

Beispiel: Gedrehtes und gespiegeltes Quellbild

  If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)
    
    LoadImage(0, #PB_Compiler_Home + "examples/Sources/Data/PureBasicLogo.bmp")
    LoadFont(0, "Impact", 20, #PB_Font_Bold)    

    If StartVectorDrawing(CanvasVectorOutput(0))
    
      FlipCoordinatesY(50, #PB_Coordinate_Source)
      RotateCoordinates(50, 50, -45, #PB_Coordinate_Source)      
      VectorSourceImage(ImageID(0), 255, ImageWidth(0), ImageHeight(0), #PB_VectorImage_Repeat)
      
      VectorFont(FontID(0), 150)
      MovePathCursor(20, 20)      
      DrawVectorText("TEXT")
    
      StopVectorDrawing()
    EndIf
    
    Repeat
      Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
  EndIf

Siehe auch

VectorSourceColor(), VectorSourceLinearGradient(), VectorSourceCircularGradient()

Unterstützte OS

Alle