CreatePopupImageMenu()

Syntax

Ergebnis = CreatePopupImageMenu(#Menue [, Flags])
Beschreibung
Erstellt ein neues leeres Popup-Menü, mit Unterstützung für Bilder bei seinen Einträgen.

Parameter

#Menue Gibt die Nummer an, mit der das neue Menü identifiziert wird. #PB_Any kann verwendet werden, um diese Nummer automatisch zu generieren.
Flags (optional) Dies kann eine Kombination der folgenden Werte sein: 
  #PB_Menu_ModernLook: Farbverlauf und modernes Aussehen aktivieren (hat nur einen Effekt auf Windows)

Rückgabewert

Gibt einen Wert ungleich Null zurück, wenn das Menü erfolgreich erstellt wurde, und Null wenn nicht. Wenn #PB_Any als #Menue Parameter verwendet wurde, dann wird bei Erfolg die generierte Nummer zurückgegeben.

Anmerkungen

Unmittelbar nach dem Erstellen des Menüs wird dieses das aktuelle Menü zum Einfügen weiterer Einträge. Es ist nun möglich, Funktionen wie z.B. MenuTitle(), MenuItem(), MenuBar(), OpenSubMenu() zum weiteren Aufbau des Menüs zu verwenden.

DisplayPopupMenu() kann benutzt werden, um dieses Popup-Menü an einer beliebigen Position auf dem Bildschirm darzustellen.

Um alle Menü-Ereignisse korrekt zu handhaben, siehe die Beschreibung der folgenden Befehle:
WaitWindowEvent() (alternativ WindowEvent())
EventWindow()
EventMenu()

Beispiel

  If OpenWindow(0, 200, 200, 200, 120, "Image Popup-Menu Example")
    If CreatePopupImageMenu(0, #PB_Menu_ModernLook)      ; hier beginnt das Erstellen des Popup-Menüs...
      MenuItem(1, "Open")      ; Sie können alle Befehle zum Erstellen eines Menüs
      MenuItem(2, "Save")      ; verwenden, ganz wie bei einem normalen Menü...
      MenuItem(3, "Save as")
      MenuItem(4, "Quit")
      MenuBar()
      OpenSubMenu("Recent files")
        MenuItem(5, "PureBasic.exe")
        MenuItem(6, "Test.txt")
      CloseSubMenu()
    EndIf
    Repeat
      Select WaitWindowEvent()     ; überprüfe Window-Ereignisse
        Case #WM_RButtonDown       ; rechte Maustaste wurde gedrückt =>
          DisplayPopupMenu(0, WindowID(0))  ; stelle jetzt das Popup-Menü dar
        Case #PB_Event_Menu        ; ein Eintrag des Popup-Menüs wurde angeklickt
          Select EventMenu()       ; ermittle den angeklickten Menü-Eintrag...
            Case 1 : Debug "Menu: Open"
            Case 2 : Debug "Menu: Save"
            Case 3 : Debug "Menu: Save as"
            Case 4 : Quit = 1
            Case 5 : Debug "Menu: PureBasic.exe"
            Case 6 : Debug "Menu: Text.txt"
          EndSelect
        Case #PB_Event_CloseWindow
          Quit = 1
      EndSelect
    Until Quit = 1
  EndIf

Siehe auch

CreatePopupMenu(), DisplayPopupMenu(), CreateMenu(), CreateImageMenu(), FreeMenu(), MenuTitle(), MenuItem(), MenuBar(), OpenSubMenu()

Unterstützte OS

Alle

<- CreateMenu() - Menu Inhaltsverzeichnis - CreatePopupMenu() ->