InsertElement()

Syntax

*Result = InsertElement(Liste())

Fügt ein neues Element vor dem aktuellen Element ein, oder am Anfang der Liste - wenn die Liste leer ist (d.h. keine Elemente beinhaltet). Dieses neue Element wird das aktuelle Element der Liste.

Parameter

Liste()

Der Variablenname der verknüpften Liste, welche mit dem NewList Befehl erstellt wurde. Sie müssen die Klammern nach dem Listennamen immer angeben.

Rückgabewert

Gibt einen Wert ungleich Null zurück, wenn das neue Element erstellt wurde, andernfalls Null. Der zurückgegebene Wert ist ein Zeiger auf die Daten des neuen Elements.

Beispiel

  ; Der einfachste Weg zur Benutzung von InsertElement
  NewList simple.w()
  InsertElement(simple())    ; Erstellt das erste neue Element in der Liste
  simple() = 23

  InsertElement(simple())    ; Aktuelle Position ist das erste Element, daher fügen wir das neue Element am Anfang der  Liste ein.
  simple() = 45              ; Das alte erste Element wird jetzt zum zweiten Element in der Liste.


  ; Dies zeigt, wie der Rückgabewert von InsertElement benutzt wird
  NewList advanced.l()
  If InsertElement(advanced()) <> 0
    advanced() = 12345
  Else
    MessageRequester("Fehler!", "Kein Speicherplatz zum Reservieren des neuen Elements", #PB_MessageRequester_OK)
  EndIf


  ; Eine kleine Struktur, um die Verwendung des Zeigers auf das neue Element zu demonstrieren
  Structure Programmer
    Name.s
    Strength.b
  EndStructure

  NewList Programmers.Programmer()  ; Die Liste zum Speichern der Elemente

  *Element.Programmer = InsertElement(Programmers())
  If *Element<>0
    *Element\Name = "Dave"
    *Element\Strength = 3   ; Wow, super-strong geek! ;)
  Else
    MessageRequester("Fehler!", "Kein Speicherplatz zum Reservieren des neuen Elements", #PB_MessageRequester_OK)
  EndIf

Siehe auch

AddElement(), DeleteElement(), ClearList()

Unterstützte OS

Alle