ComboBoxGadget()

Syntax

Ergebnis = ComboBoxGadget(#Gadget, x, y, Breite, Höhe [, Flags])

Erstellt ein ComboBox-Gadget (Auswahl-Box) innerhalb der aktuellen Gadgetliste.

Parameter

#Gadget	Gibt eine Nummer an, um das neue Gadget zu identifizieren. #PB_Any kann verwendet werden, um diese Nummer automatisch zu generieren.
x, y, Breite, Höhe	Geben die Position und die Abmessungen des neuen Gadgets an.
Flags (optional)	Gibt optionale Flags an, um das Gadget-Verhalten zu verändern. Diese können eine Kombination (verknüpft mit dem bitweisen '|' OR-Operator) der folgenden Konstanten sein: #PB_ComboBox_Editable : Macht die ComboBox editierbar #PB_ComboBox_LowerCase : Der gesamte in der ComboBox eingegebene Text wird in Kleinbuchstaben konvertiert. #PB_ComboBox_UpperCase : Der gesamte in der ComboBox eingegebene Text wird in Großbuchstaben konvertiert. #PB_ComboBox_Image : Aktiviert die Unterstützung für Bilder in Einträgen (nicht unterstützt bei editierbaren ComboBoxen auf OSX).

Rückgabewert

Gibt bei Erfolg einen Wert ungleich Null zurück, oder Null bei einem Fehler. Wenn #PB_Any als #Gadget Parameter verwendet wurde, dann beinhaltet der Rückgabewert bei Erfolg die automatisch generierte Gadget-Nummer.

Anmerkungen

Zu diesem Gadget kann mittels GadgetToolTip() eine 'Mini-Hilfe' hinzugefügt werden.

Die folgenden Befehle können benutzt werden, um auf den Listen-Inhalt zuzugreifen:

- AddGadgetItem(): fügt einen Eintrag hinzu.
- GetGadgetItemText(): ermittelt den Text des Gadget-Eintrags.
- CountGadgetItems(): ermittelt die Anzahl der Einträge in der aktuellen Auswahlbox.
- ClearGadgetItems(): entfernt alle Einträge.
- RemoveGadgetItem(): entfernt einen Eintrag.
- SetGadgetItemText(): ändert den Text des Gadget-Eintrags.

- GetGadgetState(): ermittelt die Index-Nummer (beginnend bei 0) des aktuellen Elements.
- GetGadgetText(): ermittelt den (Text-) Inhalt des aktuellen Elements.
- SetGadgetState(): ändert das ausgewählte Element.
- SetGadgetText(): ändert den anzuzeigenden Text. Wenn das ComboBoxGadget nicht editierbar ist, muss sich der Text in der Aufklapp-Liste befinden.
- GetGadgetItemData(): Gibt den Wert zurück, welcher mit dem Eintrag gespeichert wurde.
- SetGadgetItemData(): Speichert einen Wert mit dem Eintrag.

ComboBoxGadget() unterstützt die folgenden Ereignisse, welche von EventType() gemeldet werden:

  #PB_EventType_Change   : Die aktuelle Auswahl des Textes im Eingabefeld hat sich geändert.
  #PB_EventType_Focus    : Das Eingabefeld hat den Tastatur-Fokus erhalten (nur bei editierbarer ComboBox).
  #PB_EventType_LostFocus: Das Eingabefeld hat den Tastatur-Fokus verloren (nur bei editierbarer ComboBox).

Beispiel

  UsePNGImageDecoder()
  LoadImage(0, #PB_Compiler_Home + "examples/sources/Data/world.png")
  
  If OpenWindow(0, 0, 0, 270, 180, "ComboBoxGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    ComboBoxGadget(0, 10, 10, 250, 21, #PB_ComboBox_Editable)
      AddGadgetItem(0, -1, "ComboBox editable...")

    ComboBoxGadget(1, 10, 40, 250, 21, #PB_ComboBox_Image)
      AddGadgetItem(1, -1, "ComboBox item with image", ImageID(0))

    ComboBoxGadget(2, 10, 70, 250, 21)
      For a = 1 To 5
        AddGadgetItem(2, -1,"ComboBox item " + Str(a))
      Next

    SetGadgetState(0, 0)
    SetGadgetState(1, 0)
    SetGadgetState(2, 2)    ; den dritten Eintrag (beginnend bei 0) als den aktiven Eintrag setzen
    
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
  EndIf

Siehe auch

AddGadgetItem(), RemoveGadgetItem(), CountGadgetItems(), ClearGadgetItems(), GetGadgetState(), SetGadgetState(), GetGadgetText(), SetGadgetText() GetGadgetItemText(), SetGadgetItemText(), GetGadgetItemData(), SetGadgetItemData(), ExplorerComboGadget()

Unterstützte OS

Alle