EventType()

Syntaxe

Event = EventType()

Utilisez cette fonction après WindowEvent() ou WaitWindowEvent() pour savoir quel est le type du dernier évènement survenu. Les valeurs suivantes sont possibles lorsqu'un évènement du type #PB_Event_Gadget (bibliothèque Gadget) ou #PB_Event_SysTray (bibliothèque SysTray) survient:

  #PB_EventType_LeftClick       : Clic avec le bouton gauche de la souris
  #PB_EventType_RightClick      : Clic avec le bouton droit de la souris
  #PB_EventType_LeftDoubleClick : Double-clic avec le bouton gauche de la souris
  #PB_EventType_RightDoubleClick: Double-clic avec le bouton droit de la souris
  #PB_EventType_Focus           : Obtention du focus.
  #PB_EventType_LostFocus       : Perte du focus.
  #PB_EventType_Change          : Le contenu a changé.
  #PB_EventType_DragStart       : L'utilisateur a essayé de lancer Une opération Glisser & Déposer.

EventType() peut être utilisé avec les gadgets suivants :

- CanvasGadget() - Le CanvasGadget a un ensemble spécial de types d'évènement.
- ComboBoxGadget() - ExplorerListGadget()
- ExplorerTreeGadget()
- ImageGadget()
- ListViewGadget()
- ListIconGadget()
- MDIGadget()
- SpinGadget()
- StringGadget()
- WebGadget() - Le WebGadget a un ensemble spécial de types d'évènement.

(Voir la définition du gadget pour connaître les évènements valides)

Exemple

  If OpenWindow(0, 0, 0, 230, 120, "Exemple EventType() ...", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)

    ListIconGadget(1, 10, 10, 150, 100, "ListIcon", 140, #PB_ListIcon_GridLines) 
     For a= 1 To 4 
       AddGadgetItem(1, -1, "Ligne "+Str(a))
     Next a
  
     Repeat
       Event = WaitWindowEvent()
       
       Select Event
       
         Case #PB_Event_Gadget
           Select EventGadget()
             Case 1
               Select EventType()
                 Case #PB_EventType_LeftClick        : Debug "Clic avec le bouton gauche de la souris"
                 Case #PB_EventType_RightClick       : Debug "Clic avec le bouton droit de la souris"
                 Case #PB_EventType_LeftDoubleClick  : Debug "Double-clic avec le bouton gauche de la souris"
                 Case #PB_EventType_RightDoubleClick : Debug "Double-clic avec le bouton droit de la souris"
               EndSelect
           EndSelect
       
       EndSelect
     Until Event = #PB_Event_CloseWindow
  EndIf

OS Supportés

Tous