EventMenu()

Syntaxe

Resultat = EventMenu()
Description
Renvoie le numéro du menu qui a envoyé un évènement.

C'est le même évènement qui permet de connaître aussi l'icône d'une barre d'outils ou le raccourci clavier qui a été utilisé.

Arguments

Aucun.

Valeur de retour

Renvoie le numéro du menu associé à l'évènement.

Remarques

Utilisez cette fonction après un évènement de type #PB_Event_Menu renvoyé par WindowEvent() ou WaitWindowEvent().

Cette commande permet aussi de détecter quel bouton d'une barre d'outil ou quel raccourci clavier a été utilisé.

Un évènement sur une barre d'outils est similaire à un évènement sur un menu (car les barres d'outils sont la plupart du temps des racourcis pour des opérations disponibles dans les menus). Il est donc préférable de prendre les même identifiants pour l'élément du menu et le bouton de la barre d'outils qui représentent la même action, comme ça aucun code supplémentaire n'est nécessaire pour gérer la barre d'outils.

Exemple

  If OpenWindow(0, 0, 0, 230, 90, "Exemple de gestion des évènements...", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
  
  ;Raccourcis clavier
  AddKeyboardShortcut(0, #PB_Shortcut_Control | #PB_Shortcut_N, 1)
  AddKeyboardShortcut(0, #PB_Shortcut_Control | #PB_Shortcut_O, 2)
  AddKeyboardShortcut(0, #PB_Shortcut_Control | #PB_Shortcut_S, 3)
  
  ;Menu
  If CreateMenu(0, WindowID(0))
    MenuTitle("Menu")
    MenuItem(1, "Nouveau"+Chr(9)+"Ctrl+N")
    MenuItem(2, "Ouvrir"+Chr(9)+"Ctrl+O")
    MenuItem(3, "Enregistrer"+Chr(9)+"Ctrl+S")
  EndIf
  
  ;Barre d'outils
  If CreateToolBar(0, WindowID(0))
      UsePNGImageDecoder()
      Path$ = #PB_Compiler_Home  + "Examples" + #PS$ + "Sources" + #PS$ + "Data" + #PS$ + "ToolBar" + #PS$ + ""
      ToolBarImageButton(0, LoadImage(0, Path$ + "New.png"))
      ToolBarImageButton(1, LoadImage(1, Path$ + "Open.png"))
      ToolBarImageButton(2, LoadImage(2, Path$ + "Save.png"))
  EndIf
  
  Repeat
    Event = WaitWindowEvent()
    
    Select Event
 
      Case #PB_Event_Menu
        Select EventMenu()
          Case 1 : Debug "Menu 'Nouveau' cliqué ou Bouton 'Nouveau' cliqué ou 'CTRL+N' au clavier !"
          Case 2 : Debug "Menu 'Ouvrir' cliqué ou Bouton 'Ouvrir' cliqué ou 'CTRL+O' au clavier !"
          Case 3 : Debug "Menu 'Enregistrer' cliqué ou Bouton 'Enregistrer' cliqué ou 'CTRL+S' au clavier !"
        EndSelect
        
    EndSelect
  Until Event = #PB_Event_CloseWindow
EndIf

Voir aussi

WindowEvent(), WaitWindowEvent()

OS Supportés

Tous

<- EventGadget() - Window Index - EventTimer() ->