VectorSourceImage()

Syntaxe

VectorSourceImage(ImageID [, Transparence [, Largeur.d, Hauteur.d [, Options]]])
Description
Sélectionne une image en tant que source pour les opérations de dessin vectoriel telles que FillPath() ou StrokePath().

Arguments

ImageID L'image à utiliser comme source.

Utiliser la fonction ImageID() pour obtenir l'identifiant de l'image.
Transparence (optionnel) La transparence (alpha) à appliquer à l'image source.

Cette transparence est appliquée en plus de tous les pixels transparents déjà présents dans l'image source. La valeur par défaut est 255 (pas de transparence supplémentaire).
Largeur.d, Hauteur.d (optionnel) Spécifie une largeur et une hauteur de l'image.

Les valeurs sont interprétées en termes de coordonnées système #PB_Coordinate_Source. Si non spécifiées alors les dimensions de l'image source (en pixels) sont converties dans l'unité de la sortie de dessin vectoriel (taille d'origine).
Options (optionnel) Peut-être l'une des valeurs suivantes:
  #PB_VectorImage_Default: Les zones en dehors de l'image source sont transparentes (Par défaut)
  #PB_VectorImage_Repeat : L'image source est répétée pour couvrir toute la zone de dessin

Valeur de retour

Aucune.

Remarques

Ces fonctions utiliseront chaque pixel de l'image sur la sortie de dessin où il y a quelque chose à dessiner.

Voir l'aperçu de VectorDrawing pour une introduction aux différents systèmes de coordonnées.

En transformant le système de coordonnées #PB_Coordinate_Source, l'image de la source peut être transformée (déplacée, tournée, étirées, inclinée).
Voir le deuxième exemple ci-dessous pour une démonstration.

Exemple: Image source répétée

  If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)
    
    LoadImage(0, #PB_Compiler_Home + "examples/Sources/Data/PureBasicLogo.bmp")

    If StartVectorDrawing(CanvasVectorOutput(0))

      AddPathBox(50, 50, 200, 50)
      AddPathBox(150, 75, 200, 50)
      
      VectorSourceImage(ImageID(0), 255, ImageWidth(0), ImageHeight(0), #PB_VectorImage_Repeat)
      StrokePath(20)
    
      StopVectorDrawing()
    EndIf
    
    Repeat
      Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
  EndIf

Exemple: Image source tournée et renversée

  If OpenWindow(0, 0, 0, 400, 200, "VectorDrawing", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    CanvasGadget(0, 0, 0, 400, 200)
    
    LoadImage(0, #PB_Compiler_Home + "examples/Sources/Data/PureBasicLogo.bmp")
    LoadFont(0, "Impact", 20, #PB_Font_Bold)    

    If StartVectorDrawing(CanvasVectorOutput(0))
    
      FlipCoordinatesY(50, #PB_Coordinate_Source)
      RotateCoordinates(50, 50, -45, #PB_Coordinate_Source)      
      VectorSourceImage(ImageID(0), 255, ImageWidth(0), ImageHeight(0), #PB_VectorImage_Repeat)
      
      VectorFont(FontID(0), 150)
      MovePathCursor(20, 20)      
      DrawVectorText("TEXT")
    
      StopVectorDrawing()
    EndIf
    
    Repeat
      Event = WaitWindowEvent()
    Until Event = #PB_Event_CloseWindow
  EndIf

Voir aussi

VectorSourceColor(), VectorSourceLinearGradient(), VectorSourceCircularGradient()

OS Supportés

Tous

<- VectorSourceGradientColor() - VectorDrawing Index - VectorSourceLinearGradient() ->