CreatePopupMenu()

Syntaxe

Resultat = CreatePopupMenu(#Menu)
Description
Crée un nouveau menu contextuel (PopUp).

Arguments

#Menu Le numéro d'identification du menu.

#PB_Any peut être utilisé pour générer automatiquement ce numéro.

Valeur de retour

Renvoie une valeur non nulle en cas de succès, zéro sinon.
Si #PB_Any a été utilisé le numéro du menu est renvoyé en cas de succès.

Remarques

Il est possible d'utiliser des images en créant un menu popup avec CreatePopupImageMenu.

Une fois créé, il devient le menu courant et il est alors possible d'utiliser les fonctions MenuTitle(), MenuItem(), MenuBar(), et OpenSubMenu() pour remplir le menu.

La fonction DisplayPopupMenu() sera ensuite utilisée pour afficher ce menu contextuel à l'écran.

Pour gérer les évènements relatifs aux menus, voir la description des commandes suivantes:

WaitWindowEvent() (ou WindowEvent())
EventWindow()
EventMenu()

Exemple

  If OpenWindow(0, 200, 200, 220, 120, "Exemple de menu contextuel")
    If CreatePopupMenu(0)        ; La création du menu contextuel commence...
      MenuTitle("Projet")        ; Vous pouvez utiliser toutes les commandes relatives au menu,
        MenuItem(1, "Ouvrir")    ; comme si c'était un menu normal...
        MenuItem(2, "Enregistrer")
        MenuItem(3, "Enregistrer sous")
        MenuItem(4, "Quitter")
        MenuBar()
        OpenSubMenu("Fic&hiers récents")
          MenuItem(5, "PureBasic.exe")
          MenuItem(6, "Test.txt")
        CloseSubMenu()

    EndIf
    Repeat
      Event = WaitWindowEvent()
      Select Event                        ; Examine quel type d'évènement est survenu sur la fenêtre
        Case #PB_Event_RightClick         ; Le bouton droit de la souris a été clické =>
          DisplayPopupMenu(0,WindowID(0)) ; On affiche le menu contextuel
        
        Case #PB_Event_Menu      ; Un élément du menu a été sélectionné
          Select EventMenu()     ; On recupère le numéro de cet élement...
            Case 1 : Debug "Menu : Ouvrir"
            Case 2 : Debug "Menu : Enregistrer"
            Case 3 : Debug "Menu : Enregistrer sous"
            Case 4 : End
            Case 5 : Debug "Menu : PureBasic.exe"
            Case 6 : Debug "Menu : Text.txt"
          EndSelect

      EndSelect
    Until Event = #PB_Event_CloseWindow
  EndIf

Voir aussi

CreatePopupImageMenu(), DisplayPopupMenu(), CreateMenu(), CreateImageMenu(), FreeMenu(), MenuTitle(), MenuItem(), MenuBar(), OpenSubMenu()

OS Supportés

Tous

<- CreatePopupImageMenu() - Menu Index - DisableMenuItem() ->