ScrollAreaGadget()

Syntaxe

Resultat = ScrollAreaGadget(#Gadget, X, Y, Largeur, Hauteur, LargeurZoneInterne, HauteurZoneInterne [, ValeurDeplacement [, Options]])
Description
Crée un gadget zone de défilement dans la GadgetList en cours. C'est un container muni de barres de défilement.

Arguments

#Gadget Le numéro d'identification du nouveau gadget.

#PB_Any peut être utilisé pour générer automatiquement ce numéro.
X, Y, Largeur, Hauteur La position et les dimensions du nouveau gadget.
LargeurZoneInterne, HauteurZoneInterne Les dimensions de la zone interne.
Elles peuvent également être plus petits que les dimensions extérieures et dans ce cas, les barres de défilements seront masquées.
ValeurDeplacement (optionnel) Déplacement de la zone interne quand on presse sur l'une des flèches de défilement.
Options (optionnel) Peut être une combinaison de:
  #PB_ScrollArea_Flat      : Cadre simple
  #PB_ScrollArea_Raised    : Cadre élevé
  #PB_ScrollArea_Single    : Cadre enfoncé
  #PB_ScrollArea_BorderLess: Sans bordure
  #PB_ScrollArea_Center    : La zone interne est automatiquement centrée si sa taille est 
                             plus petite que les dimensions du gadget. 

Valeur de retour

Renvoie une valeur non nulle en cas de succès, zéro sinon.

Si #PB_Any a été utilisé pour le paramètre #Gadget, alors la valeur de retour est le numéro d'identification du gadget, généré automatiquement.

Remarques

Une fois créé, tous les gadgets suivants seront placés dans ce gadget.
CloseGadgetList() permet de revenir à la GadgetList précédente.
OpenGadgetList() pourra être utilisé pour ajouter des gadgets dynamiquement.

Un évènement est généré lorsque l'utilisateur déplace les ascenseurs du gadget.

Les commandes suivantes peuvent être utilisées pour agir sur un ScrollAreaGadget:
  - GetGadgetAttribute(): Avec une des constantes suivantes:
    #PB_ScrollArea_InnerWidth  : Renvoie la largeur (en pixels) de la zone interne du gadget. 
    #PB_ScrollArea_InnerHeight : Renvoie la hauteur (en pixels) de la zone interne du gadget.  
    #PB_ScrollArea_X           : Renvoie la position horizontale actuelle de l'ascenseur (en pixels).
    #PB_ScrollArea_Y           : Renvoie la position verticale actuelle de l'ascenseur (en pixels).
    #PB_ScrollArea_ScrollStep  : Renvoie la valeur du pas de défilement (en pixels).
  
  - SetGadgetAttribute(): Avec une des constantes suivantes:
    #PB_ScrollArea_InnerWidth  : Modifie la largeur (en pixels) de la zone interne du gadget. 
    #PB_ScrollArea_InnerHeight : Modifie la hauteur (en pixels) de la zone interne du gadget.  
    #PB_ScrollArea_X           : Modifie la position horizontale actuelle de l'ascenseur (en pixels).
    #PB_ScrollArea_Y           : Modifie la position verticale actuelle de l'ascenseur (en pixels).
    #PB_ScrollArea_ScrollStep  : Modifie la valeur du pas de défilement (en pixels).

  - SetGadgetColor() et GetGadgetColor() avec la constante #PB_Gadget_BackColor comme 'TypeCouleur' 
    pour changer la couleur de fond du gadget.

 L'évènement suivant est pris en charge par EventType():
  #PB_EventType_Resize: Le gadget a été redimensionné.

Exemple


  Procedure BindScrollDatas()
    SetWindowTitle(0, "ScrollAreaGadget " +
                      "(" +
                      GetGadgetAttribute(0, #PB_ScrollArea_X) +
                      "," +                      
                      GetGadgetAttribute(0, #PB_ScrollArea_Y) +
                      ")" )
  EndProcedure
  
  If OpenWindow(0, 0, 0, 405, 240, "ScrollAreaGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered) 
    ScrollAreaGadget(0, 10, 10, 390,220, 575, 575, 30)
      ButtonGadget  (1, 10, 10, 230, 30,"Bouton 1")
      ButtonGadget  (2, 50, 50, 230, 30,"Bouton 2")
      ButtonGadget  (3, 90, 90, 230, 30,"Bouton 3")
      TextGadget    (4,130,130, 230, 60,"Ceci est le contenu d'une zone de défilement !",#PB_Text_Right)
      CloseGadgetList() 
      
      BindGadgetEvent(0, @ BindScrollDatas())
        
    Repeat 
      Select WaitWindowEvent() 
        Case  #PB_Event_CloseWindow 
          End 
        Case  #PB_Event_Gadget 
          Select EventGadget()
            Case 0
              MessageRequester("Info","Un ascenseur a été utilisé ! (" +
                                      GetGadgetAttribute(0, #PB_ScrollArea_X) +
                                      "," +                      
                                      GetGadgetAttribute(0, #PB_ScrollArea_Y) +
                                      ")" ,#PB_MessageRequester_Ok)
            Case 1
              MessageRequester("Info","Le bouton 1 a été appuyé !",#PB_MessageRequester_Ok)
            Case 2
              MessageRequester("Info","Le bouton 2 a été appuyé !",#PB_MessageRequester_Ok)
            Case 3
              MessageRequester("Info","Le bouton 3 a été appuyé !",#PB_MessageRequester_Ok)
          EndSelect
      EndSelect 
    ForEver 
  EndIf

Voir aussi

GetGadgetAttribute(), SetGadgetAttribute(), ScrollBarGadget()

OS Supportés

Tous

<- ResizeGadget() - Gadget Index - ScrollBarGadget() ->