ListIconGadget()

Syntaxe

Resultat = ListIconGadget(#Gadget, X, Y, Largeur, Hauteur, TitrePremiereColonne$, LargeurTitrePremiereColonne [, Options])
Description
Crée un gadget de listes avec icônes dans la GadgetList en cours.

Arguments

#Gadget Le numéro d'identification du nouveau gadget.

#PB_Any peut être utilisé pour générer automatiquement ce numéro.
X, Y, Largeur, Hauteur La position et les dimensions du nouveau gadget.
TitrePremiereColonne$ Le titre de la première colonne dans le gadget.

Le gadget est créé avec une colonne initiale.
LargeurTitrePremiereColonne La largeur de la première colonne dans le gadget.
Options (optionnel) Peut être une combinaison de:
  #PB_ListIcon_CheckBoxes         : Affiche une case à cocher dans la première colonne.
  #PB_ListIcon_ThreeState         : La case à cocher peut avoir un état 'indéterminé'.
  #PB_ListIcon_MultiSelect        : Active le mode 'sélection multiple'.
  #PB_ListIcon_GridLines          : Affiche des lignes de séparation (non supporté sous Mac OS X).
  #PB_ListIcon_FullRowSelect      : La sélection s'étend à toute la ligne au lieu de la première colonne (Windows seulement).
  #PB_ListIcon_HeaderDragDrop     : L'ordre des colonnes peut être changé avec un glisser/déposer (drag'n'drop).
  #PB_ListIcon_AlwaysShowSelection: Affiche la selection même quand le gadget n'est plus actif (Windows seulement).
L'option #PB_ListIcon_ThreeState peut être utilisée en combinaison avec l'option #PB_ListIcon_CheckBoxes pour obtenir une case à cocher qui peut avoir un état "on", "off" et "indéterminé". L'utilisateur ne peut sélectionner que l'état "on" ou "off". L'état "indéterminé" peut être défini en utilisant la fonction SetGadgetItemState().

Valeur de retour

Renvoie une valeur non nulle en cas de succès, zéro sinon.

Si #PB_Any a été utilisé pour le paramètre #Gadget, alors la valeur de retour est le numéro d'identification du gadget, généré automatiquement.

Remarques

  - GadgetToolTip() permet d'ajouter une 'mini aide' à ce gadget.

  Les fonctions suivantes peuvent être utilisées pour agir sur le contenu de cette liste :
  - AddGadgetColumn()   : Ajoute une colonne au gadget.
  - RemoveGadgetColumn(): Supprime une colonne (ainsi que ses données).
  - AddGadgetItem()     : Ajoute un élément et éventuellement une image.
  - RemoveGadgetItem()  : Supprime un élément.
  - ClearGadgetItems()  : Supprime tous les éléments.
  - CountGadgetItems()  : Renvoie le nombre d'éléments actuellement contenus dans le gadget.
  - GetGadgetItemColor(): Renvoie la couleur du texte ou du fond de l'élément.
  - SetGadgetItemColor(): Change la couleur du texte ou du fond de l'élément.
                         (Couleur de fond pas pris en charge sur MacOS X)
  - GetGadgetItemData() : Renvoie la valeur personnalisée associée à cet élément.
  - SetGadgetItemData() : Associe une valeur personnalisée à cet élément.
  - GetGadgetItemState(): Renvoie l'état de l'élément spécifié. 
                          Ce peut être une combinaison de #PB_ListIcon_Selected 
                          et #PB_ListIcon_Checked si les 'cases à cocher' sont affichées
  - SetGadgetItemState(): Change l'état de l'élément spécifié. 
                          Ce peut être une combinaison de #PB_ListIcon_Selected
                          et #PB_ListIcon_Checked si les 'cases à cocher' sont affichées
  - GetGadgetItemText() : Renvoie le texte de l'élément spécifié. 
                          Si 'Element' = -1, alors le titre de la colonne est renvoyé.
  - SetGadgetItemText() : Change le texte de l'élément spécifié. 
                          Si 'Element' = -1, alors le titre de la colonne est modifié.
                          Comme avec AddGadgetItem(), il est possible de définir le texte de 
                          plusieurs colonnes à la fois, avec le séparateur Chr(10).
  - SetGadgetItemImage(): Modifie l'image actuelle de l'élément spécifié.
  - GetGadgetState()    : Renvoie le premier élément selectionné ou -1 s'il n'y a pas d'élément sélectionné.
  - SetGadgetState()    : Change l'élément sélectionné (tous les autres éléments sont alors désélectionnés). 
                          Si -1 est utilisé, tous les éléments seront désélectionnés.
  - GetGadgetAttribute() avec l'attribut suivant :
      #PB_ListIcon_ColumnCount: Renvoie le nombre de colonnes 
      #PB_ListIcon_DisplayMode: Renvoie le mode d'affichage du gadget (Windows uniquement)

  - SetGadgetAttribute() avec l'attribut suivant (seulement sous Windows):
      #PB_ListIcon_DisplayMode : Change le mode d'affichage du gadget. 
           Le mode peut être l'une des constantes suivantes:
           #PB_ListIcon_LargeIcon   : Mode grandes icônes
           #PB_ListIcon_SmallIcon   : Mode petites icônes
           #PB_ListIcon_List        : Mode Liste
           #PB_ListIcon_Report      : Mode Détails (colonnes, mode par défaut)

  - GetGadgetItemAttribute() / SetGadgetItemAttribute(): Avec l'attribut suivant:
      #PB_ListIcon_ColumnWidth : Renvoie / Change la largeur de la 'Colonne' spécifiée. 
      Le paramètre 'Element' est ignoré.


  Si vous voulez ajouter du contenu à un gadget ListIcon contenant plusieurs colonnes en utilisant
  AddGadgetItem(), utilisez le format "première colonne"+chr(10)+"deuxième colonne" comme paramètre Texte$. 

  - SetGadgetColor() et GetGadgetColor() avec les valeurs 'TypeCouleur' suivantes:
    #PB_Gadget_FrontColor: Couleur du texte
    #PB_Gadget_BackColor : Couleur du fond
    #PB_Gadget_LineColor : Couleur de la grille si l'option #PB_ListIcon_GridLines est utilisée.

  -  SetGadgetItemColor() et GetGadgetItemColor() avec les  valeurs 'TypeCouleur' suivantes:
    #PB_Gadget_FrontColor: Texte de l'élément.
    #PB_Gadget_BackColor : Fond de l'élément.

  Note: SetGadgetColor() n'est pas pris en charge sur la plate-forme MacOS X.
Les évènements suivants sont supportés par EventType():
  #PB_EventType_LeftClick        : Clic avec le bouton gauche de la souris, ou une case à cocher a été utilisée.
  #PB_EventType_LeftDoubleClick  : Double-clic avec le bouton gauche de la souris
  #PB_EventType_RightClick       : Clic avec le bouton droit de la souris
  #PB_EventType_RightDoubleClick : Double-clic avec le bouton droit de la souris
  #PB_EventType_Change           : L'élément sélectionné a été changé
  #PB_EventType_DragStart        : L'utilisateur a essayé de lancer une opération de 'Glisser & Déposer'.
Après un évènement #PB_EventType_DragStart, la bibliothèque Drag & Drop peut être utilisée pour commencer une opération 'Glisser & Déposer'.

Exemple

 If OpenWindow(0, 100, 100, 300, 100, "ListIconGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
   ListIconGadget(0, 5, 5, 290, 90, "Nom", 100, #PB_ListIcon_FullRowSelect | #PB_ListIcon_AlwaysShowSelection)
   AddGadgetColumn(0, 1, "Adresse", 250)
   AddGadgetItem(0, -1, "Harry Rannit"+Chr(10)+"12 Parliament Way, Battle Street, By the Bay")
   AddGadgetItem(0, -1, "Ginger Brokeit"+Chr(10)+"130 PureBasic Road, BigTown, CodeCity")

   Repeat
     Evenement = WaitWindowEvent()
   Until Evenement = #PB_Event_CloseWindow
 EndIf

Exemple

  ; Démonstration des options possibles pour le gadget liste avec icônes...
  If OpenWindow(0, 0, 0, 700, 300, "ListIconGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered) 
    ; colonne de gauche
    TextGadget    (6,  10,  10, 330, 20, "Liste avec icônes standard", #PB_Text_Center)
    ListIconGadget(0,  10,  25, 330, 70, "Colonne 1", 100)
    TextGadget    (7,  10, 105, 330, 20, "Liste avec icônes + cases à cocher", #PB_Text_Center)
    ListIconGadget(1,  10, 120, 330, 75, "Colonne 1", 100, #PB_ListIcon_CheckBoxes)  ; Liste avec icônes et cases à cocher
    TextGadget    (8,  10, 205, 330, 20, "Liste avec icônes + sélection multiple", #PB_Text_Center)
    ListIconGadget(2,  10, 220, 330, 70, "Colonne 1", 100, #PB_ListIcon_MultiSelect) ; Liste avec icônes et sélection multiple
    ; colonne de droite
    TextGadget    (9, 360,  10, 330, 20, "Liste avec icônes + lignes de séparation",#PB_Text_Center)
    ListIconGadget(3, 360,  25, 330, 70, "Colonne 1", 100, #PB_ListIcon_GridLines)
    TextGadget   (10, 360, 105, 330, 20, "Liste avec icônes + sélection de ligne entière + sélection toujours affichée",#PB_Text_Center)
    ListIconGadget(4, 360, 120, 330, 75, "Colonne 1", 100, #PB_ListIcon_FullRowSelect | #PB_ListIcon_AlwaysShowSelection)
    TextGadget   (11, 360, 205, 330, 20, "Liste avec icônes standard + mode grandes icônes",#PB_Text_Center)
    ListIconGadget(5, 360, 225, 330, 65, "", 200,#PB_ListIcon_GridLines)
    For a = 0 To 4            ; pour chacune des 5 premières listes avec icônes
      For b = 2 To 4          ; ajouter 3 colonnes supplémentaires
        AddGadgetColumn(a, b, "Colonne " + Str(b), 65)
      Next
      For b = 0 To 2          ; ajouter 4 éléments à chaque ligne des listes avec icônes
        AddGadgetItem(a, b, "Elément 1"+Chr(10)+"Elément 2"+Chr(10)+"Elément 3"+Chr(10)+"Elément 4")
      Next
    Next
    ; Ici nous changeons l'affichage de la liste avec icônes en mode grandes icônes et nous affichons une image
    If LoadImage(0, #PB_Compiler_Home+"Examples\Sources\Data\File.bmp")     ; changez le chemin/fichier contenant votre image 32x32 pixel
      SetGadgetAttribute(5, #PB_ListIcon_DisplayMode, #PB_ListIcon_LargeIcon)
      AddGadgetItem(5, 1, "Image 1", ImageID(0))
      AddGadgetItem(5, 2, "Image 2", ImageID(0))
    EndIf  
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
  EndIf

Voir aussi

AddGadgetColumn(), RemoveGadgetColumn(), AddGadgetItem(), RemoveGadgetItem(), ClearGadgetItems(), CountGadgetItems(), GetGadgetState(), SetGadgetState(), GetGadgetAttribute(), SetGadgetAttribute(), GetGadgetItemText(), SetGadgetItemText(), GetGadgetItemState(), SetGadgetItemState(), SetGadgetItemImage(), GetGadgetItemData(), SetGadgetItemData(), GetGadgetItemAttribute(), SetGadgetItemAttribute(), GetGadgetColor(), SetGadgetColor(), GetGadgetItemColor(), SetGadgetItemColor(), ExplorerListGadget(), ListViewGadget()

OS Supportés

Tous

<- IsGadget() - Gadget Index - ListViewGadget() ->