ComboBoxGadget()

Syntaxe

Resultat = ComboBoxGadget(#Gadget, X, Y, Largeur, Hauteur [, Options])

Crée un gadget Liste déroulante dans la GadgetList en cours.

Arguments

#Gadget	Le numéro d'identification du nouveau gadget. #PB_Any peut être utilisé pour générer automatiquement ce numéro.
X, Y, Largeur, Hauteur	La position et les dimensions du nouveau gadget.
Options (optionnel)	Peut être une combinaison de: #PB_ComboBox_Editable : Rend la liste déroulante éditable #PB_ComboBox_LowerCase: Tous les textes entrés dans la combobox sont convertis en minuscules #PB_ComboBox_UpperCase: Tous les textes entrés dans la combobox sont convertis en majuscules #PB_ComboBox_Image : Active le support des images dans les éléments (sauf ComboBox éditables sous MacOS X)

Valeur de retour

Renvoie une valeur non nulle en cas de succès, zéro sinon.

Si #PB_Any a été utilisé pour le paramètre #Gadget, alors la valeur de retour est le numéro d'identification du gadget, généré automatiquement.

Remarques

  - GadgetToolTip() permet d'ajouter une 'mini aide' à ce gadget.

  - AddGadgetItem()     : Ajoute un élément
  - CountGadgetItems()  : Renvoie le nombre d'éléments que contient le ComboBox. 
  - ClearGadgetItems()  : Supprime tous les éléments 
  - RemoveGadgetItem()  : Supprime un élément 
  
  - SetGadgetItemText() : Change le texte de l'élément spécifié 
  - GetGadgetItemText() : Renvoie le texte de l'élément spécifié 

  - SetGadgetItemImage(): Change l'image associée au gadget (doit être créé avec l'option #PB_ComboBox_Image).
  
  - SetGadgetState()    : Change l'élément sélectionné.
  - GetGadgetState()    : Renvoie l'index de l'élément sélectionné ou -1 si aucun élément n'a été ajouté ou sélectionné.

  - SetGadgetText()     : Change le texte affiché. Si le ComboBoxGadget n'est pas éditable, le texte doit être dans la liste déroulante.
  - GetGadgetText()     : Renvoie le contenu texte de la zone visible de la ComboBox. 

  - SetGadgetItemData() : Associe une valeur personnalisée à cet élément. 
  - GetGadgetItemData() : Renvoie la valeur personnalisée associée à cet élément.

ComboBoxGadget prend en charge les évènements suivants, voir EventType():

  #PB_EventType_Change   : La sélection du texte dans le champ d'édition a changé.
  #PB_EventType_Focus    : Le champ d'édition a reçu le focus clavier (ComboBox modifiable uniquement).
  #PB_EventType_LostFocus: Le champ d'édition a perdu le focus du clavier (ComboBox modifiable uniquement).

Exemple

  UsePNGImageDecoder()
  LoadImage(0, #PB_Compiler_Home + "examples/sources/Data/world.png")
  
  If OpenWindow(0, 0, 0, 270, 180, "ComboBoxGadget", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    ComboBoxGadget(0, 10, 10, 250, 21, #PB_ComboBox_Editable)
      AddGadgetItem(0, -1, "Liste déroulante éditable...")

    ComboBoxGadget(1, 10, 40, 250, 21, #PB_ComboBox_Image)
      AddGadgetItem(1, -1, "Liste déroulante avec une image", ImageID(0))

    ComboBoxGadget(2, 10, 70, 250, 21)
      For a = 1 To 5
        AddGadgetItem(2, -1,"Elément de liste déroulante " + Str(a))
      Next

    SetGadgetState(0, 0)
    SetGadgetState(1, 0)
    SetGadgetState(2, 2) ; Sélectionne le troisième élément (la numérotation commence à 0)
    
    Repeat : Until WaitWindowEvent() = #PB_Event_CloseWindow
  EndIf

Voir aussi

AddGadgetItem(), RemoveGadgetItem(), CountGadgetItems(), ClearGadgetItems(), GetGadgetState(), SetGadgetState(), GetGadgetText(), SetGadgetText(), SetGadgetItemImage(), GetGadgetItemText(), SetGadgetItemText(), GetGadgetItemData(), SetGadgetItemData(), ExplorerComboGadget()

OS Supportés

Tous