DrawImage()

Syntaxe

DrawImage(ImageID, X, Y [, Largeur, Hauteur])

Affiche une image sur la surface de dessin en cours.

Arguments

ImageID	Le numéro d'identification de l'image. L'ImageID peut être obtenu facilement en utilisant la fonction ImageID() de la bibliothèque Image.
X, Y	La position du coin en haut et à gauche de l'image.
Largeur, Hauteur (optionnel)	L'image sera redimensionnée en temps réel avant d'être affichée. La taille de l'image originale n'est pas modifiée.

Valeur de retour

Aucune.

Remarques

L'image sera transparente si le mode d'affichage courant DrawingMode() est utilisé avec une des options d'alpha blending (transparence) sinon l'image est simplement copiée sur la surface de dessin en cours. Pour dessiner une image en utilisant la transparence, voir la commande DrawAlphaImage().

Un certain nombre de backends (y compris WindowOutput() sous Linux) ne peuvent pas ignorer le canal alpha. Dans ce cas DrawImage() fait la même chose que DrawAlphaImage(). Pour plus de cohérence, utilisez simplement DrawAlphaImage() à la place, ce qui devrait produire la même sortie sur tous les backends.

Exemple

  If OpenWindow(0, 0, 0, 200, 200, "DrawImage", #PB_Window_SystemMenu | #PB_Window_ScreenCentered)
    If CreateImage(0, 200, 200) And StartDrawing(ImageOutput(0))
      DrawText(60,80,"CLIQUER !")
      StopDrawing() 
      ImageGadget(0, 0, 0, 200, 200, ImageID(0))
    EndIf
    If CreateImage(1, 100, 50) And StartDrawing(ImageOutput(1))
      DrawText(0,0,"PUREBASIC", $0000FF, $00FFFF)
      StopDrawing() 
    EndIf
    Repeat
      Event = WaitWindowEvent()
      If Event = #PB_Event_Gadget
        StartDrawing(ImageOutput(0))
        x=WindowMouseX(0) 
        y=WindowMouseY(0) 
        DrawImage(ImageID(1),x,y)
        StopDrawing()
        SetGadgetState(0, ImageID(0))
      EndIf
      
    Until Event = #PB_Event_CloseWindow
  EndIf

OS Supportés

Tous